Syntax
INDEX(range, row_index, [column_index])
- range—Die Gruppe der Zellen, die beurteilt werden sollen.
- row_index—Die Zeilenposition (verwendet in einer eindimensionalen Sammlung wie z. B. einer Liste) des Elements, das zurückgegeben werden soll.
- column_index—[optional]Die Spaltenposition (verwendet in einer zweidimensionalen Sammlung wie z. B. einer Tabelle) des Elements, das zurückgegeben werden soll.
Beispielnutzung
INDEX([Task Name]:[Task Name], 5
INDEX(CHILDREN([Task Name]@row), 1)
Nutzungshinweise
- Der Bereich kann eine Funktion sein, die mehrere Werte zurückgibt, zum Beispiel: ANCESTORS oder CHILDREN.
-
Sie können die MATCH-Funktion innerhalb der INDEX-Funktion nutzen, um ein Element aus einem Bereich basierend auf der relativen Position einer Wertes in einem Bereich zurückzugeben. (Siehe das Beispiel im Anschluss.)
-
Sie können die COLLECT-Funktion innerhalb der INDEX-Funktion nutzen, um ein Element aus einem Bereich basierend auf den Werten zurückzugeben, die die angegebenen Kriterien erfüllen. (Siehe das Beispiel im Anschluss.)
Beispiele
Dieses Beispiel verweist auf folgende Blattinformationen:
| Kleidungselement | Transaktion insgesamt | Verkaufte Einheiten | Stückpreis | Auf Lager? | |
|---|---|---|---|---|---|
| 1 | T-Shirt | 1.170,00 | 78 | 15,00 | true (wahr) |
| 2 | Hose | 1.491,00 | 42 | 35,50 | false (falsch) |
| 3 | Jacke | 812,00 | 217 | 200,00 | true (wahr) |
Es folgen einige Beispiele zur Verwendung von INDEX in einem Blatt anhand der obigen Tabelle:
|
Formel |
Beschreibung |
Ergebnis |
|---|---|---|
|
=INDEX([Kleidungselement]:[Verkaufte Einheiten], 1, 3) |
Gibt den Wert in der Spalte „Verkaufte Einheiten“ für Zeile 1 aus. |
78 |
|
=INDEX(COLLECT([Transaktion insgesamt]:[Transaktion insgesamt], [Auf Lager?]:[Auf Lager?], true), 1) |
Erfasst die Werte in der Spalte „Transaktion insgesamt“ für Zeilen, bei denen das Kontrollkästchen in der Spalte „Auf Lager?“ aktiviert ist (true, wahr), und gibt den ersten Eintrag in dieser Sammlung zurück. |
1.170,00 $ |
|
=INDEX([Stückpreis]:[Stückpreis], MATCH(“Jacke”, [Kleidungselement]:[Kleidungselement], 0)) |
Gibt den Wert in der Spalte „Stückpreis“ für die Zeile zurück, die den Wert „Jacke“ in der Spalte „Kleidungselement“ enthält. |
200 $ |
|
=INDEX([Auf Lager]:[Auf Lager], MATCH(“Jacke”, [Kleidungselement]:[Kleidungselement], 0)) |
Gibt den Wert in der Spalte „Auf Lager“ für die Zeile zurück, die den Wert „Jacke“ in der Spalte „Kleidungselement“ enthält. |
true (wahr) |