Créer une référence de cellule ou de colonne dans une formule

S’applique à

Smartsheet
  • Pro
  • Business
  • Enterprise

Lorsque vous créez des formules, il est possible d’ajouter des valeurs provenant d’autres cellules ou colonnes de la feuille. Utilisez des références de cellule ou de colonne à cette fin. Vous pouvez créer une référence à une cellule individuelle, à une plage de cellules ou à une colonne entière.

Il est également possible de faire référence à des données provenant d’autres feuilles. Pour plus d’informations sur la manière de faire référence à des données d’autres feuilles, reportez-vous à Formules : faire référence à des données d’autres feuilles.

Résumé des types de références pour les formules

Voici un aide-mémoire que vous pouvez utiliser quand vous créez vos propres formules.

Pour faire référence à cet élément Utiliser le format suivant Exemple
Cellule individuelle Nom de la colonne, numéro de la ligne =Budget1
Le nom de la colonne contient un espace ou se termine par un nombre Mettez le nom de la colonne entre crochets. =[Colonne A]1
=DAY([T1]1)
Référence absolue (se réfère toujours à cette cellule, cette ligne ou cette colonne spécifique) Ajoutez le caractère $ devant le nom de la colonne, le numéro de la ligne ou les deux. =$[Colonne A]$1
=[Colonne B]$1
=$[Colonne C]1
Cellules multiples non adjacentes Utilisez une virgule entre les références de cellule. =SUM(Budget1, Dépenses4, [Bénéfices prévus]20)
Une plage de cellules de la même colonne Faite référence à la première cellule de la plage, puis la dernière cellule et séparez-les par : (deux points). =SUM(Budget1:Budget12)
Une colonne entière (et toute nouvelle cellule ajoutée) Le nom de la colonne séparé par : (deux points). =SUM(Budget:Budget)
Une plage de cellules sur des colonnes multiples Faites référence à la cellule supérieure la plus à droite, puis à la cellule inférieure la plus à gauche et séparez-les par :(deux points). =SUM(Janvier1:Mars5)
Une cellule individuelle, une plage de cellules ou des colonnes entières d’une autre feuille Saisissez le nom d’une référence à une autre feuille créée précédemment entre accolades. =COUNT({ma_feuille Plage1})

Description plus détaillée des types de références

Faire référence à des cellules individuelles

Lorsque vous créez votre formule, vous pouvez sélectionner une cellule pour y faire référence et utiliser les données qu’elle contient dans votre formule. (Vous pouvez également saisir manuellement le nom de la colonne et le numéro de la ligne pour faire référence à la cellule)

La formule de la colonne Valeur en stock de la feuille de gestion des stocks suivante multiplie la valeur de la ligne 1 de la colonne Prix par la valeur de la ligne 1 de la colonne Stock, par exemple :

Formule avec référence individuelle

La formule renvoie 2 994,00 $, soit la valeur totale de cet article :

Résultat avec référence individuelle

Noms des colonnes de référence qui comportent des espaces ou se terminent par des nombres

Si un nom de colonne contient des espaces, des caractères spéciaux ou des nombres, vous devez le mettre entre crochets pour éviter toute ambiguïté :

=[Budget annuel]1 + [Budget annuel]2

=[T1]1 + [T2]1

=[Risque/problème]5 + [Imprévu/réduction]5

Créer une référence absolue

Dans certaines situations, quand vous faites référence à un tableau à l’aide de la fonction VLOOKUP, vous devez empêcher Smartsheet d’actualiser automatiquement les références de cellule lorsqu’une formule est déplacée ou copiée. Pour ce faire, créez une référence de cellule absolue. (Vous trouverez des détails sur la fonction VLOOKUP dans l’article Référence de fonction)

Pour créer une référence absolue, tapez $ (le signe dollar) devant le nom de la colonne ou le numéro de la ligne dans la référence de cellule de votre formule. Si vous déplacez ou copiez la formule suivante, par exemple, les noms des colonnes et les numéros des lignes ne changeront pas pour les références de cellule :

=$[Colonne A]$1 * $[Colonne B]$1

La formule suivante n’utilise des références absolues que pour les numéros de ligne. Si vous déplacez ou copiez la formule, les références de colonne sont modifiées en fonction du nouvel emplacement de la formule :

=[Colonne A]$1 * $[Colonne B]$1

La formule suivante permet de conserver les références absolues aux colonnes. Si vous déplacez ou copiez la formule, les numéros de ligne sont modifiés en fonction du nouvel emplacement de la formule :

=$[Colonne A]1 * $[Colonne B]1

Faire référence à une plage de cellules de la même colonne

Pour faire référence à une plage de cellules, tapez : (deux points) entre les deux références de cellule.

La formule en bas de la colonne Valeur en stock de la feuille de gestion des stocks suivante additionne les valeurs de la ligne 1 à la ligne 6 de la même colonne, par exemple :

Additionner une plage

La formule renvoie 40 763,75 $, soit le total de toutes les valeurs en stock :

Résultat de l’addition d’une plage

Faire référence à une colonne entière

Vous pouvez faire référence à une colonne entière dans une formule, avec toutes les cellules remplies qu’elle contient. La formule suivante additionne toutes les valeurs de la colonne Budget annuel et elle est actualisée lorsque des lignes sont ajoutées ou supprimées, par exemple :

=SUM([Budget annuel]:[Budget annuel])

REMARQUE : si une formule est placée dans la colonne à laquelle elle fait référence, elle ne fait pas référence à la cellule dans laquelle elle se trouve.Si vous placez la formule de l’exemple ci-dessus dans une colonne nommée Budget annuel, par exemple, la formule SUM additionne toutes les cellules sauf celle dans laquelle elle se trouve.

Référence à une plage sur des colonnes multiples

Pour faire référence à une plage de valeurs d’une ligne sur plusieurs colonnes, faites référence à la première et à la dernière colonne de la ligne.

La formule de la colonne Stock total de la feuille de gestion des stocks suivante additionne les valeurs des colonnes Stock A, Stock B et Stock C de la ligne 1, par exemple :

Somme de colonnes multiples

 

La formule renvoie 998, soit le stock total des trois emplacements :

Résultat de la somme de colonnes multiples