Fonction CORRESPONDANCE

Renvoie la position relative d'une valeur dans une plage (table de correspondance). La première position est 1.
Exemple d'utilisation
MATCH("Tâche A"; [Nom de la tâche]1:Terminé5)
Syntaxe
MATCH(
  • search_value
  • plage
  • [
    search_type
    ]
)
  • search_value
    La valeur à rechercher.
  • plage
    La plage de cellules (table de correspondance) dans laquelle effectuer la recherche.
  • search_type
    —[facultatif]
    La valeur par défaut est 1. La méthode de recherche, dépend du mode tri de la plage : tri par ordre croissant (1), non triée (0) ou tri par ordre décroissant (-1).
Notes d'utilisation

Smartsheet calcule la position relative d’une valeur de recherche en comptant les cellules de gauche à droite (par colonne), puis de haut en bas (par ligne). Dans un tableau de recherche composé de deux colonnes, la cellule de la ligne supérieure de la colonne la plus à gauche est la première position, 1.

Pour l'argument optionnel [search_type] :

  • 1 (la valeur par défaut) trouve la plus grande valeur inférieure ou égale à search_value (nécessite que la plage soit triée par ordre croissant).
  • 0 trouve la première correspondance exacte (la plage peut ne pas être triée).
  • -1 trouve la plus petite valeur supérieure ou égale à search_value (nécessite que la plage soit triée par ordre décroissant).
Exemples

Cet exemple se réfère aux informations de la feuille suivante :

Ligne n°

Article d’habillement

Total de la transaction

Unités vendues

Prix unitaire

Date de commande

1

T-shirt

1 170,00 $

78

15,00$

12/02/19

2

Pantalon

1 491,00$

42

35,50$

15/02/19

3

Veste

812,00$

217

200,00$

20/02/19

 

 

Compte tenu du tableau ci-dessus, voici quelques exemples d’utilisation d’INDEX dans une feuille :

Formule

Description

Résultat

=MATCH("Pantalon", [Article d’habillement]:[Article d’habillement], 0)

Retourne la position de la ligne « Pantalon » dans la colonne « Article d’habillement ».

2

=MATCH(42, [Unités vendues]1:[Prix unitaire]3, 0)

Retourne la position de la valeur numérique 42 du tableau à deux colonnes, où 78 serait en 1ère position et 200,00 $ en 6ème position.

3

=MATCH(DATE(2019, 2, 12), [Date de commande]:[Date de commande])

Retourne la position de la date du 12 février 2019, en utilisant la fonction DATE(), dans la colonne « Date de commande ».

1

=INDEX([Prix unitaire]:[Prix unitaire], MATCH("Veste", [Article d’habillement]:[Article d’habillement], 0))

Renvoie la valeur de la colonne « Prix unitaire » pour la ligne contenant la valeur « Veste » dans la colonne « Article d’habillement ».

200,00$