Aplica a

Smartsheet
  • Pro
  • Business
  • Enterprise

Crear una referencia a una celda o columna en una fórmula

PLANS

  • Smartsheet
  • Pro
  • Business
  • Enterprise

Cuando cree fórmulas, podrá incluir valores de otras celdas o columnas de la planilla. Eso se hace con referencias a celdas o a columnas. Puede crear una referencia a una celda individual, a un rango de celdas o a la totalidad de una columna.

También se pueden hacer referencias a datos de otras planillas. Para obtener información sobre cómo hacer referencia a datos de otras planillas, consulte Fórmulas: Hacer referencia a datos de otras planillas.

Resumen de los tipos de referencia de fórmulas

Aquí le ofrecemos una hoja de trucos que puede usar cuando desarrolle fórmulas.

Para hacer referencia a esto Aplique este formato Ejemplo
Celda individual Nombre de la columna, número de fila =Presupuesto1
El nombre de la columna contiene un espacio o termina con un número Encierre el nombre de la columna entre corchetes. =[Columna A]1
=DÍA([Q1]1)
Referencia absoluta (siempre hace referencia a esa celda, fila o columna específica) Escriba un signo $ delante del nombre de la columna, del número de fila o de ambos. =$[Columna A]$1
=[Columna B]$1
=$[Columna C]1
Varias celdas discontinuas Utilice una coma entre cada referencia a celdas. =SUMA(Presupuesto1, Gastos4, [Ingresos proyectados]20)
Un rango de celdas en la misma columna Haga referencia a la primera celda del rango y, luego, a la última; sepárelas con un ":" (dos puntos). =SUMA(Presupuesto1:Presupuesto12)
La totalidad de una columna (incluidas todas las celdas recién agregadas) El nombre de la columna se separa con un ":"  (dos puntos). =SUMA(Presupuesto:Presupuesto)
Un rango de celdas en varias columnas Haga referencia a la primera celda desde arriba a la derecha, luego a la última en el ángulo inferior izquierdo; sepárelas con un ":" (dos puntos). =SUMA(Enero1:Marzo5)
Una celda individual, un rango de celdas o columnas completas de otra planilla Escriba el nombre de una referencia creada previamente a otra planilla, entre llaves. =RECUENTO({mi_hoja1 Intervalo1})

Descripción más detallada de los tipos de referencia

Hacer referencia a celdas individuales

Mientras esté creando su fórmula podrá seleccionar una celda para hacerle referencia y trabajar con los datos de esa celda en su fórmula. (También puede escribir manualmente el nombre de la columna y el número de fila para hacer referencia a la celda.)

Por ejemplo: la fórmula presente en la columna Valor de inventario de la siguiente planilla de administración de inventario multiplicará el valor de la fila 1 de la columna Precio por el valor de la fila 1 de la columna Stock:

Fórmula de referencia individual

La fórmula devuelve $2.994,00, el valor total de ese elemento:

Resultado de referencia individual

Hacer referencia a nombres de columnas que tienen espacios o terminan con números

Si el nombre de una columna contiene espacios, cualquier caracter especial o números, debe encerrarla entre corchetes para evitar ambigüedades:

=[Presupuesto anual]1 + [Presupuesto anual]2

=[T1]1 + [T2]1

=[Riesgo/Problema]5 + [Contingencia/Mitigación]5

Crear una referencia absoluta

Es posible que, en algunas situaciones, como al hacer referencia a una tabla con la función VLOOKUP, tenga que evitar que Smartsheet actualice automáticamente referencias a celdas cuando se mueve o copia una fórmula. Para hacerlo, cree una referencia absoluta a una celda. (Puede encontrar detalles sobre la función VLOOKUP en el artículo Referencia de funciones.)

Para crear una referencia absoluta, escriba $ (un signo de peso) delante del nombre de la columna o del número de fila en la referencia a la celda de su fórmula. Por ejemplo: si mueve o copia la siguiente fórmula, los nombres de las columnas y los números de fila no cambiarán para las referencias a celdas:

=$[Columna A]$1 * $[Columna B]$1

La siguiente fórmula tiene referencias absolutas solo a los números de fila. Si mueve o copia la fórmula, las referencias a las columnas cambiarán respectivamente en función de la nueva ubicación de la fórmula:

=[Columna A]$1 * [Columna B]$1

La siguiente fórmula mantendrá referencias absolutas a las columnas. Si mueve o copia la fórmula, los números de fila cambiarán respectivamente en función de la nueva ubicación de la fórmula:

=$[Columna A]1 * $[Columna B]1

Hacer referencia a un rango de celdas en la misma columna

Para hacer referencia a un rango de celdas, escriba un ":" (dos puntos) entre las dos referencias a las celdas.

Por ejemplo: la fórmula de la parte inferior de la columna Valor de inventario de la siguiente planilla de administración de inventario sumará los valores de la fila 1 a la fila 6 de la misma columna:

Rango de suma

La fórmula devuelve $40,763.75, el total de todos los valores del inventario:

Resultado del rango de suma

Hacer referencia a la totalidad de una columna

Puede hacer referencia a la totalidad de una columna en una fórmula, incluidas todas las celdas con contenido de la columna. Por ejemplo: la siguiente fórmula suma todos los valores de la columna de Presupuesto anual y se actualizará a medida que se agreguen o quiten filas de la columna:

=SUMA([Presupuesto anual]:[Presupuesto anual])

NOTA: Si se coloca una fórmula en la columna a la que está haciendo referencia, no referenciará a la celda en la que se encuentra la fórmula. Por ejemplo: si colocar la fórmula del ejemplo anterior en una columna de nombre Presupuesto anual, la fórmula SUM sumaría todas las celdas salvo por la que contiene la fórmula. 

Hacer referencia a un rango en varias columnas

Para hace referencia a un rango de valores en una fila que se extiende en varias columnas, referencia la primera y la última columna de la fila.

Por ejemplo: la fórmula presente en la columna de Stock total de la siguiente planilla de administración del inventario sumará los valores de las columnas Stock A, Stock B y Stock C en la fila 1:

Sumar valores de varias columnas

 

La fórmula devuelve 998, el stock total de las tres ubicaciones:

Resultado de sumar valores de varias columnas

¿El artículo resultó útil?
SiNo